一 小型加料过程介绍:
其加料程序采用HONEYWELL DCS的编程语言CL语言编写,CL程序运行在控制站,其可靠性高,而且可以直接在DCS操作站上显示加料过程和时间,减少了对加料系统现场巡检的工作量。
烯烃厂催化剂小型加料系统提供三种加料方式:
1、 全自动加料方式:由ARGG优化软件自动设置加料时间(ASTARTTM)和间隔时间(ASTOPTM),或者由操作员设定,置STARTFL为ON状态,置AMFL为ON状态;
2、 半自动加料方式:在全自动加料方式时,可以手动设置加料时间(MSTARTTM),置AMFL为OFF状态,这时执行手动加料,手动加料时间到后,继续执行自动加料过程;
3、 手动状态:置STARTFL为OFF状态,即停止自动加料过程,这时操作员可以在流程图上开关加料球阀,执行加料过程。
二 程序编辑步骤:
1、 修改系统当前目录:SP NET>&E01;
2、 编辑源程序:ED CL1103.CL;
3、 重新编译时删除旧的目标文件: DL NET>&E01>10902999.NO,可以查看清单文件 PR CL1103.LS;
4、 编译源程序:CL NET>&E01>CL1103.CL -UL,产生目标文件10902999.NO如出现错误,可查看错误文件 PR CL1103.LE;
5、 调出PROCESS MODULE程序点 CL1103的细目画面,下装并启动程序(START-EXEC-LOAD-START-ENTER);
6、 调试CL程序:建立临时组GROUP(400),通过手动给信号,检查程序运行状态是否符合程序设计方框图。
三 小型加料程序变量定义
位 号 DCS组态UNIT/UCN/HPM/SLOT 位号说明 备 注
PB1103 1/1/9/1 加料球阀控制信号 数字组合点(DC),OPEN和CLOSED两种状态
AMFL 1/1/9/30 手动\自动加料开关 软件点(FLAG),ON为自动,OFF为手动
STARTFL 1/1/9/31 加料启动信号 软件点(FLAG),ON为启动加料,OFF为停止加料
ASTARTTM 1/1/9/140 自动加料时开阀时间 软件点(NUMERIC),整数,0-3600妙
ASTOPTM 1/1/9/141 自动加料时关阀时间 软件点(NUMERIC),整数,0-7200妙
MSTARTTM 1/1/9/142 手动加料时开阀时间 软件点(NUMERIC),整数
四 程序方框图:
程序方框图
五 小型加料源程序:
SEQUENCE CL1103(HPM;POINT CL1103)
EXTERNAL PB1103,AMFL,STARTFL,ASTARTTM,ASTOPTM,MSTARTTM
―――――――――――――――――――――――――――――――――――――――――
PHASE START
STEP ONE
GTOPEN:IF STARTFL.PV=OFF THEN GOTO GTOPEN
―――――――――――――――――――――――――――――――――――――――――
――打开加料球阀
SET PB1103.MODATTR=PROGRAM
OPEN PB1103
SET PB1103.MODATTR=OPERATOR
――加料球阀开阀延时ASTARTTM.PV时间,有手动加料信号或停止加料信号时退出开阀延时
WAIT (AMFL.PV=OFF OR STARTFL.PV=OFF)(WHEN ASTARTTM.PV SECS :GOTO GTCLOSE)
――执行手动加料,并判断是否有停止加料信号
IF AMFL.PV=OFF THEN WAIT STARTFL.PV=OFF(WHEN MSTARTTM.PV SECS :GOTO GTAMFL)
――判断是否有停止加料信号,有就停止加料
IF STARTFL.PV=OFF THEN(SET PB1103.MODATTR=PROGRAM;
& CLOSED PB1103;
& SET PB1103.MODATTR=OPERATOR;
& GOTO GTOPEN)
―――――――――――――――――――――――――――――――――――――――――
GTAMFL:SET AMFL.PV=ON
――关闭加料球阀
GTCLOSE: SET PB1103.MODATTR=PROGRAM
CLOSED PB1103
SET PB1103.MODATTR=OPERATOR
――关闭加料球阀延时,有手动加料信号或停止加料信号时退出关阀延时
WAIT (AMFL.PV=OFF OR STARTFL.PV=OFF)(WHEN ASTOPTM.PV SECS
& :GOTO GTOPEN)
――执行手动加料,并判断是否有停止加料信号
IF AMFL.PV=OFF THEN (SET PB1103.MODATTR=PROGRAM;
& OPEN PB1103;
& SET PB1103.MODATTR=OPERATOR;
& WAIT STARTFL.PV=OFF(WHEN MSTARTTM.PV SECS :GOTO GTAMFL))
――判断是否有停止加料信号,有就停止加料
IF STARTFL.PV=OFF THEN GOTO GTOPEN
―――――――――――――――――――――――――――――――――――――――
END CL1103